
/*

Objective(s) 
- This code demonstrates to create a report to print the contact details of all the party ledgers and make this report available on the browser
- A TDL Object helps to make this report available on browser.
- Once the object is defined, use the object in a predefined collection called List of Custom Browser Reports.

Last modification 
-	Altered on 27/04/2020

*/


[#Menu: Gateway of Tally]
	
	Add	: Item	: "Party Contact Details"		: Display				: TSPL Smp Party Contact Details
	

[!Report: TSPL Smp Party Contact Details]

	Title			: $$LocaleString:"Party Contact Details"
	Form			: TSPL Smp Party Contact Details
	
	/*You can use the new attribute Date Picker Type under Report definition to specify the type of date picker
	required in the report that is being displayed in the browser. This attribute accepts the values Range,
	Day or None.*/
	
	Date Picker Type: None
	
[Form: TSPL Smp Party Contact Details]
	
	Add		: Part	: TSPL Smp Party Contact Details
	Button			: Print Button
	Full Height 	: Yes
	Full Width		: Yes
	
[Part: TSPL Smp PartyContactDetails]
	
	Lines			: TSPLPartyContactDetailsTitle, TSPLPartyContactDetails
	Repeat			: TSPLPartyContactDetails	: TSPLPartyContactDetailsColl
	Common Border	: Yes
	Scroll			: Vertical
	Border			: Thin Bottom
	
	[Line: TSPLPartyContactDetailsTitle]
		
		Use				: TSPLPartyContactDetails
		Local 	: Field	: TSPLPartyContactDetSlNo		: Set as	: "Sl. No."
		Local 	: Field	: TSPLPartyContactDetCmp		: Set as	: "Name of the Party"
		Local	: Field	: TSPLPartyContactDetName		: Set as	: "Contact Person"
		Local	: Field	: TSPLPartyContactDetEmail		: Set as	: "E-mail ID"	
		Local	: Field	: TSPLPartyContactDetPhone		: Set as	: "Phone Number"		
		Local	: Field	: TSPLPartyContactDetAddress	: Set as	: "Address"
		Local	: Field	: Default						: Style		: Normal Bold
		Local	: Field	: Default						: Delete	: Border
		Border			: Thin Top Bottom
		
	[Line: TSPLPartyContactDetails]
		
		Fields			: TSPLPartyContactDetSlNo, TSPLPartyContactDetCmp, TSPLPartyContactDetName, TSPLPartyContactDetEmail, TSPLPartyContactDetPhone, TSPLPartyContactDetAddress 
	
						
		[Field: TSPLPartyContactDetSlNo]
			
			Set as		: $$Line
			Align		: Centre
			Width		: 7
									
		[Field: TSPLPartyContactDetCmp]
			
			Set as		: $MailingName
			Border		: Thin Left
			Style		: Normal
			Align		: Left
			Width		: 30
				
		[Field: TSPLPartyContactDetName]
			
			Set as		: $LedgerContact
			Border		: Thin Left
			Width		: 20
			Align		: Left
					
		[Field: TSPLPartyContactDetEmail]
			
			Set as		: $Email
			Border		: Thin Left
			Width		: 20
			Align		: Left
						
		[Field: TSPLPartyContactDetPhone]
			
			Set as		: $LedgerPhone
			Border		: Thin Left	
			Width		: 15
			Align		: Left
			
		[Field: TSPLPartyContactDetAddress]
			
			Set as		: $$FullList:Address:$Address
			Border		: Thin Left
			;;Width		: 80
			Full Width	: Yes
			Align		: Left
			                                           
	
[Collection: TSPLPartyContactDetailsColl]
	
	Type				: Ledger
	Child Of			: $$GroupSundryDebtors
	
;;Any objects under this collection will be listed in the browser reports


[#Collection: List of Custom Browser Reports]
     
   Add	: Object		: TSPL Party Contact Details
    
[Object: TSPL Party Contact Details]
    
;;The method name accepts the name of the report to be displayed in the browser report list
	
    Name            	: "Customized Report - Party Contact Details" 
	
;; The value of this method can be True or False. If the value is True, the report will get displayed via a collection 
;; otherwise the report will open directly

    IsCollection    	: False
	
;; If the value of the method IsCollection is true then it accetps collection name and if the value of the method 
;; IsCollection is false then it accepts report name.

    Definition Name     : "TSPL Smp Party Contact Details" 
	
;; It specifies the condition to make the report available on the browser based on the security settings.

    IsAccessAvailable 	: $$Allow:Display:AccountsMasters
	
;; It specifies the condition to make the report available based on the F11 features.	

    IsFeatureEnabled   	: $$IsAccountingOn or $$IsInventoryOn
	
                                        
;; End-of-File